日期:2013-08-16  浏览次数:20797 次

一、使用Command对象和Parameter对象传递参数

本讲将主要使用Microsoft SQL Server7.0数据库,先建立一个连接文件AdoSQL7.asp备用,以后用到时不再特别说明。

<% 'AdoSQL7.asp

Option Explicit

Response.Expires = 0



'第一部分: 建立连接

Dim Cnn, StrCnn

Set Cnn = Server.CreateObject("ADODB.Connection")

StrCnn = "Provider=sqloledb; User ID=sa; Password=; Initial Catalog=pubs; Data Source=ICBCZJP"

Cnn.Open StrCnn

%>

注意:自己使用时要将Data Source设为你的数据库服务器所在的机器名。

另外,以前使用Access数据库时,用Microsoft Access97可以很方便的查看字段及数据,而使用SQL Server数据库,尤其是并不在数据库服务器,而是在另一台机器上调试ASP脚本时,要查看字段及数据便需另外安装工具,这里向你提供一个工具:Msqry32.exe(Microsoft Query),这个文件随Office97安装,一般位于目录“Microsoft OfficeOffice”下。

例wuf70.asp:

<%@ LANGUAGE="VBSCRIPT" %>

<!--#include file="AdoSQL7.asp"-->

<!--#include file="adovbs.inc"-->

<% ' wuf70.asp

Dim cmdTest, prmTest, rsTest

'创建 Command 对象

Set cmdTest = Server.CreateObject("ADODB.Command")

‘Recordset、Command对象都可以通过ActiveConnection属性来连接Connection对象

cmdTest.ActiveConnection = Cnn

'SQL命令 - 含两个参数, 用 ? 表示

cmdTest.CommandText = "Update jobs Set job_desc = ? Where job_id = ?"

'设命令类型为 SQL 语句

cmdTest.CommandType = adCmdText

'Prepared 属性决定是否将 SQL 命令先行编译,将其设为True,可以加快运行

cmdTest.Prepared = True



'创建 Parameter 对象

Set prmTest=cmdTest.CreateParameter("job_desc",adVarChar,adParamInput,50,"网络")

'将数据追加到 Parameters 数据集合中

cmdTest.Parameters.Append prmTest



Set prmTest = cmdTest.CreateParameter("job_id",adSmallInt,adParamInput,,"12")

cmdTest.Parameters.Append prmTest



'执行修改 ? 不需要返回结果,简单的使用cmdTest.Execute 就可以了

cmdTest.Execute



'重新设置参数运行 ? 便可修改另一条数据

cmdTest.Parameters("job_id") = "1"

cmdTest.Parameters("job_desc") = "测试"

cmdTest.Execute



'重新设置参数运行

cmdTest("job_id") = "14"

cmdTest("job_desc") = "金融"

cmdTest.Execute



Set rsTest = Cnn.Execute("Select job_id,job_desc From jobs")

While Not rsTest.EOF

Response.Write rsTest(0) & rsTest(1) & "<br>"

rsTest.MoveNext

Wend



Cnn.close : Set prmTest = Nothing

Set cmdTest = Nothing: Set Cnn = Nothing

%>

分析:

1.Command对象的CreateParameter方法用来为SQL命令或存储过程建立参数对象,共有五个参数(五个参数都是可选项):

第一个参数:参数对象的名称;

第二个参数:参数对象的数据类型,种类太多,还是参考ADO帮助吧,这里adVarChar(字符串值)、adSmallInt(2 字节带符号整型);

第三个参数:参数类型。可以是:adParamInput(指示输入参数)、adParamOutput( 指示为输出参数)、adParamReturnValue(指示为返回值)、adParamUnknown(指示参数类型无法确定)、adParamInputOutput(指示为输入/输出参数);

第四个参数:参数的数据长度,最好指定为与数据库中对应字段长度相等,以免使用时出错,尤其数据类型为VarChar时,如果是整型或日期型则不必提供该值;

第五个参数:参数的设置初值。

2.cmdTest.Parameters.Append方法增加一个Parameter对象到Parameters数据集合中,从本例中也可看到如何使用多个参数。

3.从本例可以看到,只需要重新设定输入参数,便可执行对其他数据的修改,非常方便,这一思路在编程时也是最常用的方法之一。

4.重设参数,既可以使用cmdTest.Parameters,也可以省略为cmdTest("job_id")。



二、在ASP中使用存储过程

什么是存储过程(存储过程位于数据库服务器中,是一个SQL语句的集合,可包含一个或多个SQL语句)、怎样创建存储过程不属于本讲座的内容,本讲座主要是举例说明在ASP中如何调用存储过程。

使用存储过程的好处是大大的,存储过程比在ASP脚本中运行SQL命令效率更高;可以提高整体性能并减轻网络负载(减少了在网络服务器和数据服务器之间的交互);可以优化ASP代码和增强代码灵活性等等。

(一)在存储过程中使用输入参数

本例中使用的存储过程为SQL Server7.0自带的“byroyalty”,里面的一条SQL语句非常简单,无非是多了一个CREATE PROCEDURE byroyalty,并且有一个输入参数为@percentage:

CREATE PROCEDURE byroyalty @percentage int

AS

select au_id from titleauthor

where titleauthor.royaltyper = @percentage

serve by www.cidu.net

例wuf71.asp

<% @LANGUAGE = VBScript %>