日期:2010-09-24  浏览次数:21181 次

既然 RSS 是一种 XML 格式的文档,那么我们就应当可以对后台数据库中的数据按照条件进行筛选、组织,然后通过 ASP 生成 XML 格式的数据流,最后发送到客户端进行浏览。

数据的选取、汇集是 Asp 的拿手好戏,关键在于怎么生成 XML 格式的数据流。其实 Asp 也已经有自己的解决办法,就是在写数据前对 response 对象的 ContentType 属性进行定义。如果 response.ContentType 的取值为 "text/xml",就会向浏览者发送 XML 格式的数据流。

在 IE 浏览器中调用 RSS 源的方法和普通的链接没有什么区别,格式是:
<a type="application/rss+xml" href="RssFeed.asp">RSS说明</a>
其中 type="application/rss+xml" 加不加好象没有什么区别。

以下程序段是创建某网站栏目的 RSS feed 的源代码,文件名为 RssFeed_news.asp。
其中,变量 sXmlClear 用于声明产生的文档是一段 XML 格式的文档,该声明是可选的,以保持与旧版本 XML 的向后兼容性。
sRssHead 定义 Rss 的基本元素。RSS feed 通常由 4 个主要元素构成:<channel>,<image>,<item> 和 <textinput>。其中,<channel> 元素是必需的,<item> 元素至少要出现一次。<textinput> 和 <image> 元素是可选的,是否使用要视具体情况而定。
<channel> 元素包含 Channel(RSS feed 的来源)的一个简单描述。<title> 是频道的名称/标题;<link> 是与频道内容对应的包含了完整内容的那个网页的 URL;<description> 是与 <channel> 的内容有关的简单描述;<language> 代表语言。还有一些别的属性,不是太常用。
<item> 元素用于对数据库中的记录进行描述。<item> 一般有若干项,对应了一个 Rss feed 的数据集合。

<!-Filename:RssFeed_news.asp:-->
<% Option explicit %>
<!-- #include file="./conn.inc" -->

<%
Dim sSQL, rs, sCrLf, sXmlClear, sRssHead, sRssEnd
sCrLf = chr(13) & chr(10) '回车+换行

sXmlClear = "<?xml version='1.0' encoding='gb2312'?>" & sCrLf

sRssHead = "<rss version='2.0'>" & sCrLf
sRssHead = sRssHead & "<channel>" & sCrLf
sRssHead = sRssHead & "<title>RSS创建示例</title>" & sCrLf
sRssHead = sRssHead & "<description> RSS创建示例</description>" & sCrLf
sRssHead = sRssHead & "<link>http://1234.com/</link>" & sCrLf
sRssHead = sRssHead & "<language>zh-cn</language>" & sCrLf
sRssHead = sRssHead & "<docs>RSS创建示例r</docs>" & sCrLf
sRssHead = sRssHead & "<generator>Rss Generator By 1234.com</generator>" & sCrLf

sRssEnd = "</channel></rss>"

Response.CharSet="gb2312" '数据集
Response.ContentType="text/xml" '数据流格式定义

'输出:
Response.write sXmlClear
Response.write sRssHead

sSQL="select top 15 * from news order by sortid desc"
Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open sSQL, s_Conn, 1, 1
if not (rs.eof and rs.bof) then
do while not rs.eof
response.write "<item>" & sCrLf
response.write "<title> " & rs("f_topic") & " </title>" & sCrLf
response.write "<link> " & "http://www.1234.com/_news/show_a_new.asp?autoid=" &

rs("f_i_autoid") & " </link>" & sCrLf
response.write "<author> " & rs("f_author") & " </author>" & sCrLf
response.write "<pubDate> " & rs("f_datetime") & " </pubDate>" & sCrLf
response.write "</item>" & sCrLf & sCrLf
rs.movenext
loop
end if
rs.close
set rs=nothing

Response.write sRssEnd
%>

IE 中的调用格式是:<a href="http://www.1234.com/_news/RssFeed_news.asp">技术新闻

RSS</a>。如果用一些客户端软件订阅该 RSS,订阅的 Url 就是

http://www.1234.com/_news/RssFeed_news.asp。